stats/codeage.plot at master · curl/stats · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
# SVG output
set terminal svg size 1920,1080 dynamic font ",24"

# title
set title "Source code age\n{/*0.5Lines of code written per two-year segment}" font ",48"
# where's the legend
set key left top font ",22"

# Identify the axes
#set xlabel "Time"
set y2label "Lines of code (including blanks and comments)"

set grid y2tics
unset border

# time formated using this format
set timefmt "%Y-%m-%d"
set xdata time

set y2range [0:]
set xrange ["2000-01-01":]

set xtics rotate 3600*24*365.25 nomirror out
unset mxtics
#set ytics out
set y2tics mirror out
unset ytics

load "stats/logo.include"

# set the format of the dates on the x axis
set format x "%Y"

# instead of, e.g.,  200000, show 200k
set format y2 "%.0s%c"

set datafile separator ";"
plot ARG1.'/codeage.csv' using 1:16 axes x1y2 with filledcurves above fc "#D1BBD7" title "≥ 2026", \
 ARG1.'/codeage.csv' using 1:15 axes x1y2 with filledcurves above fc "#AE76A3" title "≥ 2024", \
 ARG1.'/codeage.csv' using 1:14 axes x1y2 with filledcurves above fc "#882E72" title "≥ 2022", \
 ARG1.'/codeage.csv' using 1:13 axes x1y2 with filledcurves above fc "#1965B0" title "≥ 2020", \
 ARG1.'/codeage.csv' using 1:12 axes x1y2 with filledcurves above fc "#5289C7" title "≥ 2018", \
 ARG1.'/codeage.csv' using 1:11 axes x1y2 with filledcurves above fc "#7BAFDE" title "≥ 2016", \
 ARG1.'/codeage.csv' using 1:10 axes x1y2 with filledcurves above fc "#4EB265" title "≥ 2014", \
 ARG1.'/codeage.csv' using 1:9 axes x1y2 with filledcurves above fc "#90C987" title "≥ 2012", \
 ARG1.'/codeage.csv' using 1:8 axes x1y2 with filledcurves above fc "#CAE0AB" title "≥ 2010", \
 ARG1.'/codeage.csv' using 1:7 axes x1y2 with filledcurves above fc "#F7F056" title "≥ 2008", \
 ARG1.'/codeage.csv' using 1:6 axes x1y2 with filledcurves above fc "#F6C141" title "≥ 2006", \
 ARG1.'/codeage.csv' using 1:5 axes x1y2 with filledcurves above fc "#F1932D" title "≥ 2004", \
 ARG1.'/codeage.csv' using 1:4 axes x1y2 with filledcurves above fc "#E8601C" title "≥ 2002", \
 ARG1.'/codeage.csv' using 1:3 axes x1y2 with filledcurves above fc "#DC050C" title "≥ 2000", \
 ARG1.'/codeage.csv' using 1:2 axes x1y2 with filledcurves above fc "#72190E" title "< 2000"